asan_arm64.s

Documentation: runtime

     1// Copyright 2021 The Go Authors. All rights reserved.
     2// Use of this source code is governed by a BSD-style
     3// license that can be found in the LICENSE file.
     4
     5//go:build asan
     6
     7#include "go_asm.h"
     8#include "textflag.h"
     9
    10#define RARG0 R0
    11#define RARG1 R1
    12#define RARG2 R2
    13#define RARG3 R3
    14#define FARG R4
    15
    16// Called from instrumented code.
    17// func runtime·doasanread(addr unsafe.Pointer, sz, sp, pc uintptr)
    18TEXT	runtime·doasanread(SB), NOSPLIT, $0-32
    19	MOVD	addr+0(FP), RARG0
    20	MOVD	sz+8(FP), RARG1
    21	MOVD	sp+16(FP), RARG2
    22	MOVD	pc+24(FP), RARG3
    23	// void __asan_read_go(void *addr, uintptr_t sz, void *sp, void *pc);
    24	MOVD	$__asan_read_go(SB), FARG
    25	JMP	asancall<>(SB)
    26
    27// func runtime·doasanwrite(addr unsafe.Pointer, sz, sp, pc uintptr)
    28TEXT	runtime·doasanwrite(SB), NOSPLIT, $0-32
    29	MOVD	addr+0(FP), RARG0
    30	MOVD	sz+8(FP), RARG1
    31	MOVD	sp+16(FP), RARG2
    32	MOVD	pc+24(FP), RARG3
    33	// void __asan_write_go(void *addr, uintptr_t sz, void *sp, void *pc);
    34	MOVD	$__asan_write_go(SB), FARG
    35	JMP	asancall<>(SB)
    36
    37// func runtime·asanunpoison(addr unsafe.Pointer, sz uintptr)
    38TEXT	runtime·asanunpoison(SB), NOSPLIT, $0-16
    39	MOVD	addr+0(FP), RARG0
    40	MOVD	sz+8(FP), RARG1
    41	// void __asan_unpoison_go(void *addr, uintptr_t sz);
    42	MOVD	$__asan_unpoison_go(SB), FARG
    43	JMP	asancall<>(SB)
    44
    45// func runtime·asanpoison(addr unsafe.Pointer, sz uintptr)
    46TEXT	runtime·asanpoison(SB), NOSPLIT, $0-16
    47	MOVD	addr+0(FP), RARG0
    48	MOVD	sz+8(FP), RARG1
    49	// void __asan_poison_go(void *addr, uintptr_t sz);
    50	MOVD	$__asan_poison_go(SB), FARG
    51	JMP	asancall<>(SB)
    52
    53// func runtime·asanregisterglobals(addr unsafe.Pointer, n uintptr)
    54TEXT	runtime·asanregisterglobals(SB), NOSPLIT, $0-16
    55	MOVD	addr+0(FP), RARG0
    56	MOVD	n+8(FP), RARG1
    57	// void __asan_register_globals_go(void *addr, uintptr_t n);
    58	MOVD	$__asan_register_globals_go(SB), FARG
    59	JMP	asancall<>(SB)
    60
    61// func runtime·lsanregisterrootregion(addr unsafe.Pointer, n uintptr)
    62TEXT	runtime·lsanregisterrootregion(SB), NOSPLIT, $0-16
    63	MOVD	addr+0(FP), RARG0
    64	MOVD	n+8(FP), RARG1
    65	// void __lsan_register_root_region_go(void *addr, uintptr_t n);
    66	MOVD	$__lsan_register_root_region_go(SB), FARG
    67	JMP	asancall<>(SB)
    68
    69// func runtime·lsanunregisterrootregion(addr unsafe.Pointer, n uintptr)
    70TEXT	runtime·lsanunregisterrootregion(SB), NOSPLIT, $0-16
    71	MOVD	addr+0(FP), RARG0
    72	MOVD	n+8(FP), RARG1
    73	// void __lsan_unregister_root_region_go(void *addr, uintptr_t n);
    74	MOVD	$__lsan_unregister_root_region_go(SB), FARG
    75	JMP	asancall<>(SB)
    76
    77// func runtime·lsandoleakcheck()
    78TEXT	runtime·lsandoleakcheck(SB), NOSPLIT, $0-0
    79	// void __lsan_do_leak_check_go(void);
    80	MOVD	$__lsan_do_leak_check_go(SB), FARG
    81	JMP	asancall<>(SB)
    82
    83// Switches SP to g0 stack and calls (FARG). Arguments already set.
    84TEXT	asancall<>(SB), NOSPLIT, $0-0
    85	MOVD	RSP, R19                  // callee-saved
    86	CBZ	g, call                   // no g, still on a system stack
    87	MOVD	g_m(g), R10
    88
    89	// Switch to g0 stack if we aren't already on g0 or gsignal.
    90	MOVD	m_gsignal(R10), R11
    91	CMP	R11, g
    92	BEQ	call
    93
    94	MOVD	m_g0(R10), R11
    95	CMP	R11, g
    96	BEQ	call
    97
    98	MOVD	(g_sched+gobuf_sp)(R11), R5
    99	MOVD	R5, RSP
   100
   101call:
   102	BL	(FARG)
   103	MOVD	R19, RSP
   104	RET
View as plain text